{ config, lib, pkgs, modulesPath, ... }:
let chicago95 = 
  pkgs.stdenv.mkDerivation rec {
    pname = "chicago95";
    version = "20230216";

    src = pkgs.fetchgit {
      url = "https://github.com/grassmunk/Chicago95.git";
      rev = "4c39951284add04941adc6ce5a68a778590b93d1";
      hash = "sha256-PwNuVAcJ6FZlALdHAvgX8H56bOkZ0llXGd09ETj4enQ=";
    };

    nativeBuildInputs = with pkgs; [
      which
    ];

    installPhase = ''
      pwd
      ls -lah
      for p in cursors fonts gtk_theme icons backgrounds doc; do
        make install_$p DESTDIR=$out prefix=
      done
    '';

    meta = with lib; {
      description = "A rendition of everyone's favorite 1995 Microsoft operating system for Linux";
      homepage = "https://github.com/grassmunk/Chicago95";
      platforms = platforms.all;
    };
  };
in
{
  services.xserver.windowManager.icewm.enable = true;
  services.xserver.windowManager.windowmaker.enable = true;
  services.xserver.desktopManager.xfce.enable = true;

  environment.systemPackages = with pkgs; [
    # theming
    onestepback
    feh
    lxappearance
    chicago95
    libsForQt5.qtstyleplugins
    libsForQt5.qt5ct
  ];
}