defmodule ShardWeb.ChatChannel do
  use ShardWeb, :channel

  require Logger

  def join("chat:" <> room_name, payload, socket) do
    if authorized?(payload) do

      pid = Shard.Manager.find_or_start %SApp.Chat.Manifest{channel: room_name}
      socket = assign(socket, :pid, pid)

      GenServer.cast(pid, {:subscribe, self()})
      send(self(), :after_join)
      
      {:ok, socket}
    else
      {:error, %{reason: "unauthorized"}}
    end
  end

  def join("privchat:" <> room_name, payload, socket) do
    if authorized?(payload) do

      pk_list = room_name |> String.split(",") |> Enum.map(&Base.decode16!/1)
      pk_list = [socket.assigns.pk | pk_list] |> Enum.sort() |> Enum.uniq()

      pid = Shard.Manager.find_or_start(SApp.Chat.PrivChat.Manifest.new(pk_list))
      socket = assign(socket, :pid, pid)

      GenServer.cast(pid, {:subscribe, self()})
      send(self(), :after_join)
      
      {:ok, socket}
    else
      {:error, %{reason: "unauthorized"}}
    end
  end

  def handle_info(:after_join, socket) do
    GenServer.call(socket.assigns.pid, {:read_history, nil, 100})
    |> Enum.each(fn {{pk, msgbin, _sign}, true} ->
        {_ts, msg} = SData.term_unbin msgbin
        nick = SApp.Identity.get_nick pk
        push(socket, "shout", %{
          name: nick,
          pk16: Shard.Keys.pk_display(pk),
          message: msg,
        }) 
      end)
    GenServer.cast(socket.assigns.pid, :mark_read)
    {:noreply, socket}
  end

  def handle_info({:chat_recv, _chan, {pk, msgbin, _sign}}, socket) do
    {_ts, msg} = SData.term_unbin msgbin
    nick = SApp.Identity.get_nick pk
    Logger.info("#{inspect self()} :chat_recv #{inspect msg}")
    push socket, "shout", %{"name" => nick,
      "pk16" => Shard.Keys.pk_display(pk),
      "message" => msg}
    GenServer.cast(socket.assigns.pid, :mark_read)
    {:noreply, socket}
  end

  def handle_info({:chat_send, _, _}, socket) do
    GenServer.cast(socket.assigns.pid, :mark_read)
    {:noreply, socket}
  end

  # Channels can be used in a request/response fashion
  # by sending replies to requests from the client
  def handle_in("ping", payload, socket) do
    {:reply, {:ok, payload}, socket}
  end

  # It is also common to receive messages from the client and
  # broadcast to everyone in the current topic (room:lobby).
  def handle_in("shout", payload, socket) do
    pk = socket.assigns.pk
    nick = SApp.Identity.get_nick pk
    payload = Map.put(payload, "name", nick)
    payload = Map.put(payload, "pk16", Shard.Keys.pk_display pk)

    GenServer.cast(socket.assigns.pid, {:chat_send, pk, payload["message"]})
    broadcast socket, "shout", payload
    {:noreply, socket}
  end

  # Add authorization logic here as required.
  defp authorized?(_payload) do
    true
  end
end